10 '** FXSET.BAS
20 '** FX SERIES PRINTER SET UP PROGRAM
30 '** CREATED BY: R. NIES               2/14/84
40 ' Upload errors corrected and provision for ELITE mode made
41 ' by Don Watkins [76003,252] on 3/18/84. Lines changes noted as 'dww 3/84
50 CLS
60 KEY OFF
70 DIM I$(20),P$(20),S$(20),A$(10)
80 '
90 'RESET THE PRINTER TO DEFAULT VALUS
100 LPRINT CHR$(27)+"@";
110 '
120 GOSUB 880
130 '
140 'PRINT THE MENU
150 '
160 Z$="##"
170 COLOR 2,0
180 LOCATE 1,22 : PRINT"**** PRINTER SET UP PROGRAM ****"
190 LOCATE 3,15 :PRINT"Character Pitch:"
200 LOCATE 3,45 :PRINT"Forms Control:";
210 COLOR 3,0
220 Z=5 : Y = 5
230 FOR X= 1 TO 5
240 LOCATE Z,15 : PRINT USING Z$ ;X;:PRINT ".) ";I$(X);
250 LOCATE Z,45 : PRINT USING Z$; X+Y;:PRINT ".) ";I$(X+Y);
260 Z=Z+1
270 NEXT X
280 COLOR 2,0
290 LOCATE 11,15 :PRINT"Line Spacing:"
300 LOCATE 11,45: PRINT"Special Fonts:"
310 COLOR 3,0
320 Z=13 : Y = 5
330 FOR X= 11 TO 15
340 LOCATE Z,15 : PRINT USING Z$ ;X;:PRINT ".) ";I$(X);
350 LOCATE Z,45 : PRINT USING Z$; X+Y;:PRINT ".) ";I$(X+Y);
360 Z=Z+1
370 NEXT X
380 COLOR 1,0
390 LOCATE 5,13: PRINT"*";
400 LOCATE 7,43: PRINT"*";
410 LOCATE 13,13: PRINT"*";
420 LOCATE 13,43: PRINT"*";
430 '
440 'PRINT THE INSTRUCTIONS
450 '
460 LOCATE 19,15: PRINT"The Default Values Are Indicated By The `*'";
470 COLOR 2,0
480 LOCATE 21,20: PRINT"The New Selection(s) Are ";
490 P=45
500 COLOR 4,0
510 LOCATE 23,21: INPUT"ENTER SELECTION (99 To End) ";A$(A)
520 IF A$(A)=""THEN GOTO 510
530 IF A$(A)="99" THEN GOTO 760
540 V = VAL(A$(A))
550 IF (V < 1) OR (V > 20) THEN LOCATE 23,51: PRINT"   ";: GOTO 510
560 COLOR 2,0
570 LOCATE 21,P: PRINT A$(A);",";
580 '
590 'CHECK FOR SPECIAL ENTRIES
600 '
610 IF A$(A)="6"THEN GOSUB 1120
620 IF A$(A)="9" THEN GOSUB 1120
630 IF A$(A)="10" THEN GOSUB 1120
640 IF A$(A)="14" THEN GOSUB 1120
650 IF A$(A)="15" THEN GOSUB 1120
660 'IF A$(A)="18" THEN GOSUB 1120                        'dww 3/84
670 '
680 'ORGANIZE THE VALUES
690 '
700 Q=VAL(A$(A))
710 P$(A)=S$(Q)
720 A=A+1
730 P=P+4
740 LOCATE 23,51: PRINT"             ";
750 GOTO 500
760 '
770 ' OUTPUT THE SET UP STRING
780 '
790 'RESET IF 99 WAS FIRST ENTRY
800 IF A = 0 THEN LPRINT CHR$(27)+"@";
810 '
820 'IF NOT SEND THE NEW VALUES
830 FOR X = 0 TO A-1
840 LPRINT P$(X);
850 NEXT X
860 END
870 '
880 'STRING VALUES
890 '
900 I$(1)="STANDARD (10CPI)":S$(1)=""
910 I$(2)="CONDENSED (16.5CPI)":S$(2)=CHR$(15)
920 I$(3)="ELITE (12CPI)":S$(3)=CHR$(27)+"M"
930 I$(4)="EXPANDED (DOUBLE)":S$(4)=CHR$(27)+"W1"
940 I$(5)="EMPHASIZED":S$(5)=CHR$(27)+"E"
950 I$(6)="FORM LENGTH (n LINES)"
960 I$(7)="SKIP OVER PERF ON":S$(7)=CHR$(27)+"N"+CHR$(6)
970 I$(8)="SKIP OVER PERF OFF":S$(8)=CHR$(27)+"O"
980 I$(9)="LEFT MARGIN INDENTED n"
990 I$(10)="RIGHT MARGIN INDENTED n"
1000 I$(11)="6 LINES/INCH":S$(11)=CHR$(27)+"2"
1010 I$(12)="8 LINES/INCH":S$(12)=CHR$(27)+"0"
1020 I$(13)="10 LINES/INCH":S$(13)=CHR$(27)+"1"
1030 I$(14)="n/72 SPACING"
1040 I$(15)="n/216 SPACING"
1050 I$(16)="FX80 FONT":S$(16)=""
1060 I$(17)="ITALICS":S$(17)=CHR$(27)+"4"
1070 I$(18)="ELITE":S$(18)=CHR$(27)+"M"                         'dww 3/84
1080 I$(19)="SUBSCRIPT":S$(19)=CHR$(27)+"S0"
1090 I$(20)="SUPERSCRIPT":S$(20)=CHR$(27)+"S1"
1100 RETURN
1110 '
1120 'GET SPECIAL VALUE
1130 COLOR 20,0
1140 LOCATE 23,55:INPUT"n = ";N
1150 IF A$(A)="6" THEN S$(6)=CHR$(27)+"C"+CHR$(N) :RETURN
1160 IF A$(A)="9" THEN S$(9)=CHR$(27)+"l"+CHR$(N) :RETURN
1170 IF A$(A)="10" THEN S$(10)=CHR$(27)+"Q"+CH$(N) :RETURN
1180 IF A$(A)="14" THEN S$(14)=CHR$(27)+"A"+CHR$(N) :RETURN
1190 IF A$(A)="15" THEN S$(15)=CHR$(27)+"3"+CHR$(N):RETURN      'dww 3/84
1200 'RETURN                                                    'dww 3/84
1210 '
1220 'LOAD THE IBM FONT 2
1230 '
1240 'IF YOU HAVE A PROGRAM LIKE `FXer' MERGE IT HERE.
1250 '
1260 RETURN
                                                                                     